Сообщений в теме: 30

[Skywalker]

Подскажите,пожалуйста, как переделать срипт СЕО турбо тэйлор под оси?
Чтоб он после 100 делал осил клос, а не горгетки хотел делать.

[Rarst alSava]

Пощелкай схемы в нем, там должны быть схемы которые подстраиваются в зависимости от твоего скилкапа.

[Naughty Cat]

Skywalker (22.07.2005 23:05) писал:

Подскажите,пожалуйста, как переделать срипт СЕО турбо тэйлор под оси?
Чтоб он после 100 делал осил клос, а не горгетки хотел делать.

до 103.9 у меня качал на оилах.
Врпочем говорят, что это зависит от типа съеденного скролла. Просто активируй на +20 и попробуй продолжить прокачку.

[Skywalker]

Это я понимаю. Мне нужно конкретно, как,что и где изменить в скрипте, чтоб он после 100 оил клос делал.

[TAR]

запости сюда скрипт, тока не ссылкой а целиком. лень его искать

[Skywalker]

Пожалуйста.
Не нашёл,файл вставить, вот по-глупому.
;-----------------------------------------------------------
; Script Name: CEOTurboTailor
; Author: CEO
; Version: 1.86
; Client Tested with: 4.0.1b
; EUO version tested with: 1_41_103
; Shard OSI / FS: OSI
; Revision Date: 012704
; Public Release: 012704
; Purpose: Trains tailoring to 120 FAST.
;-------------------------------------------------------------
; Instructions:
;
; 1. Start CEOTurboCutter
; 2. Start CEOTurboTailor
; 3. Identify Secure (or it'll use your bankbox automatically)
; 4. Identify Resource container.
; Make sure to have cloth, leather, bone, sewing kits.
; Also iron ingots and tinker tools if you will be making your own kits.
; NOTE: ANY opened bag with resources will be used, the resource
; container is also used to drop cut bandages to when making
; oil cloths.
; The script automatically learns your bank/secure/resources setup using
; persistant vars *524 and *525. To reset these, start the script away from the
; bank or out of range of your secure container.
; 5. If you're making bone armor, be sure to be within 2 paces of a house's trash barrel OR
; at a bank with a trash can within 12 paces. Script automatically finds these and will use
; them to discard your bone armor.
;
; Note: Your paperdoll MUST be visible and the backpack in the paperdoll VISIBLE with
; nothing blocking it's view as the script drops direct to the backpack.
; The resource container in your secure or bank box must also be visible with nothing
; block it. It can be just about any valid container type.
;
initevents
set %version 1.86
set %scriptstart #scnt
set %gaintime %scriptstart
linespercycle 100
;=============================================
; User configuration section
; Most of these defaults should be fine. Please understand
; what you're doing before changing.
;=============================================
; Set to #true to leave EUO window opened.
set %debug #false
; Set to #true to enable system messages to the journal during setup
; This is mostly for people that are having StayOnTop problems.
set %sysmessages #false
; Will autoset to #true if hiding is over 35. Otherwise set to #true
; to force trying, or #false to never try. Set to #true if you're in a house. It'll always work.
set %hideme N/A
; set this to unhide after x number of unsuccesful attempts without a gain. Sometimes working another skill
; will kick in a gain. To disable this, set to a high number like 9999. If you haven't gained after 9999 attempts
; something else is wrong!
set %unhideat 80
; Minimum skill required to try hiding. Set lower if you want to attempt even if you
; may fail. In tenths, defaults to 35.0.
set %hideskillreq 350
; Set these to your x/y cords for the EasyUO menu window
set %menu_windowx 535
set %menu_windowy 20
; Set these to your x/y cords for bank box or secure screen position.
set %bank_securex 460
set %bank_securey 390
; Set these to your x/y cords for resource bag on screen position.
set %resource_bagx 630
set %resource_bagy 390
; Set these to your x/y cords for the house's trash barrel. This MUST be out of the area
; the tailoring/tinker menu comes up!
set %trash_barrelx 0
set %trash_barrely 0
; Always use normal leather.
; 1=normal, 2=spined, 3=horned, 4=barbed.
set %leathertype 1
; If you'd rather make bone items near the top levels set to #true otherwise
; it'll do studded sleeves instead of bone helmets.
set %makebone #false
; Minimum skill required before attempting to tinker sewing kits or
; tinker's tools. In tenths, defaults to 30.0
set %tinkerskillreq 300
; Maximum number of sewing kits to tinker at one time - Based on Weight. Min of 3. Force to your own number if you want.
set %maxsewingkits #maxweight / 60
;set %maxsewingkits 5
; Set to #true if you're slow and/or having timing issues. If persistant timing
; problems see the wait vars further down and change to higher numbers.
set %slowconnection #false
; These are the types for the bank dumpsters. There may be more so I've included
; them in this section.
set %bankgarbage IKF_BUD
; Leave this at N/A for a more intelligent bank checking method and less chance of saying
; "BANK BANK" at your house. If it fails to detect a bank you use, set to #true.
set %bankfound N/A
; Estimate costs of doing business: Change these to reflect your shard
set %cost_of_cloth 2
set %cost_of_leather 8
set %cost_of_bone 10
; set to #true if you want to select what to make and not use the skills table
set %makeyourown #false
; If you're on a freeshard with different menu configurations the below variables are for the
; click points for Make Last RELATIVE to the Tailor gump's position of 50/50.
; You may need to adjust to your shard's menu configuration.
; NOTE: This script was written for OSI and latest client. The Make Item feature and these
; variables may allow you to use it, but no promises!
set %makelast_clickx 285
set %makelast_clicky 410
; set this to a maximum skillcap if you want to stop at a certain point.
; Leave at N/A to use your real cap. In tenths, IE, GM=1000, 99.5=995, etc...
set %maxskillcap n/a
; Close EasyUO when the menu window is closed.
set %exitonclose #true
;
set %uose_menu #true
;
; If you use RKCharacterSetup you can change the custom stuff on a per character basis
; with that method..
CALL RKCharacterSetup.txt  CEOTurboTailor
;=============================================
; NOTHING BELOW THIS LINE SHOULD NEED CHANGING.
; DO SO AT YOUR OWN RISK!
;=============================================

set %gumpx 50
set %gumpy 50
if %slowconnection
{
set %gumpwait 10
set %wait1 20
set %wait2 30
set %longwait 70
}
else
{
set %gumpwait 5
set %wait1 10
set %wait2 15
set %longwait 40
}
if %sysmessages && sys notin #opts
{
set %sysmessages #false
display ok Unable to use Event Sysmessages. You have the$flag enabled in the script, but EasyUO must also$
+be configured. See :$$Options->Configuration->Enable Event Sysmessages$$ in the EasyUO menu bar to turn it on.$$Script Halted.
menu hide
sound
halt
}
if G in #charstatus
{
event macro 6 0
wait %wait1
}
set %oilcloth RTI
set %bandaids ZLF
set %clothtypes BUI_CUI_GUI_DUI
set %bolttypes IAG_CAG_NAG_BAG_ZZF
set %scissortypes KAG_JAG
set %weighcheck #true
set %getbolts #true
set %leathertypes JJG_MJG
set %bonetypes GUF
set %bonearmortypes PPH_WPH_BQH_QPH_AQH_VPH_YPH_ZPH_CQH_XPH
set %invalidtypes IWI_XVL_ , %clothtypes , _ , %bolttypes , _
set %lcolor1 0
set %lcolor2 2220
set %lcolor3 2117
set %lcolor4 2129
set %defaultleathertype %leathertype
set %bagtypes CKF_LKF_ZJF_JIF_HIF_KIF_IIF_CUD_HKF_VMF_BUD_WMF_TMF_UMF_KKF_ZTD_
+ABG_CTD_AUD_SPF_JKF_OKF_OVH_KUD
set %chesttypes JIF_HIF_IIF_KIF
set %chest_findmod 32_19
set %trashbarreltype BKF
set %tinkertools JTL_GTL
set %makelasttinker #false
set %ironingots ENK
set %sewingkittypes HAG
set %trashcanid N/A
set %unhidetext ?!.,'/
; Zero Stats
set %attempts 0
set %unhidecount 0
for %i 1 3
{
set %attempts . %i 0
set %clothused . %i 0
set %leatherused . %i 0
set %boneused . %i 0
}
;recall saved stats
if *526 <> N/A
set %attempts3 *526
if *527 <> N/A
set %clothused3 *527
if *528 <> N/A
set %leatherused3 *528
if *529 <> N/A
set %boneused3 *529
if *530 <> N/A
set %_530 *530
if %maxsewingkits > 10
set %maxsewingkits 10
if %maxsewingkits < 3
set %maxsewingkits 3
gosub statusbarup
gosub SetUpSkills
set *521 %product . %currentitem
set *520 cut
wait %wait2
set *520 pause
gosub WaitforPause
linespercycle 40
set %firstmenu #true
gosub initmenu
gosub AutoSetup
if %makeyourown
gosub makeyourown
gosub RemoveNonEssentials
gosub MaterialsToResource %ironingots ingots
gosub cutupbolts
set %firstattempt #true
set %leatherselected #false
set %retrycount 11
;--------------------------------------------------- Gentleman, start your scissors!
MainLoop:
set *520 cut
;wait %gumpwait
if G in #charstatus
set #menubutton pause
if #menubutton <> N/A
gosub #menubutton
gosub DisplayElapsedTime
gosub HideMe
finditem %sewkitid C_ , %backpackID
if #findkind = -1 || %retrycount > 10
{
gosub CheckForResources
gosub FindSewingKit
gosub UseSewingKit
wait %gumpwait
set %retrycount 0
}
if #contname <> generic_gump
{
set %retrycount %retrycount + 1
wait %gumpwait
menu delete status
menu text status 50 5 Waiting for tailoring menu , ( , %retrycount , ).
goto MainLoop
}
set %gumpx #contposx
set %gumpy #contposy
if  %firstattempt
{
set *521 %product . %currentitem
if %leather . %currentitem <> 0 && ! %leatherselected
{
menu delete status
menu text status 50 5 Selecting leather type.
wait %gumpwait
gosub makefirstitem 16 %leathertype
if ! #result
goto MainLoop
set %leatherselected #true
set %firstattempt #true
wait %gumpwait
set %retrycount 11
goto MainLoop
}
menu delete status
menu text status 50 5 Making first item.
str len %desc . %currentitem
if #strres > 16
menu font size 8
menu delete making
menu text making 107 35 %desc . %currentitem
menu font size 9
wait %gumpwait
if ! %makeyourown
{
gosub MakeFirstItem %category . %currentitem %selection . %currentitem
if ! #result
goto MainLoop
}
set %firstattempt #false
wait %wait2
}
else
{
menu delete status
menu text status 50 5 Make last.
set %clickx %gumpx + %makelast_clickx
set %clicky %gumpy + %makelast_clicky
click %clickx %clicky f
}
set %retrycount 0
wait %gumpwait
if *522 = CUTTING-
wait %wait2 %wait2
if *522 = CUTTING--
wait %longwait %longwait
if *522 = CUTTING---
{
menu delete status
menu text status 50 5 Waiting for cutter.
set *520 PAUSE
gosub WaitforPause
}
gosub CheckForResources
if ! #result
goto MainLoop
gosub DisplayResourceStats
gosub CheckForGain
if ( %product . %currentitem = %oilcloth ) && ( %weightcheck ) && ( #weight > #maxweight )
{
gosub MaterialsToResource %bandaids bandaids
set %weightcheck #false
}
Goto MainLoop
halt

sub CheckForResources
menu delete status
menu text status 50 5 Checking resources.
set %return #true
set %loopcheck 0
cloth:
if %cloth . %currentitem <> 0
{
gosub countresource %resource . %currentitem
if #result < %cloth . %currentitem
{
if *522 <> IDLE && *522 <> Paused
goto cloth
set %loopcheck %loopcheck + 1
if %loopcheck > 5
{
display ok Hmm, there appears to be a problem getting$
+more cloth, you may be overwieght or$have too many items in your backpack.$$
+Hit OK, correct the problem and then resume script.$$Pausing.
gosub NeedMore Cloth
gosub CheckforMultipleCloths
menu delete status
menu text status 50 5 Getting more cloth.
set %return #false
set %getbolts #true
wait %wait1
set %loopcheck 0
goto cloth
}
if %product . %currentitem = %oilcloth
gosub MaterialsToResource %bandaids bandaids
set %weightcheck #true
set %amt ( %maxweight - #weight - 10 ) * 10
set %boltamount ( %maxweight - #weight - 10 ) / 5
if %amt < %cloth . %currentitem
set %amt  %cloth . %currentitem
if %boltamount < 1
goto cloth2
if %getbolts
{
menu delete status
menu text status 50 5 Check for bolts ( , %boltamount , ).
gosub GetMoreResources %bolttypes %boltamount
if ! #result
{
set %getbolts #false
goto cloth
}
wait %wait2
gosub cutupbolts
set %return #false
wait %wait1
goto cloth
}
cloth2:
menu delete status
menu text status 50 5 Getting more cloth ( , %amt , ).
gosub GetMoreResources %resource . %currentitem %amt
if ! #result
{
gosub NeedMore Cloth
gosub CheckforMultipleCloths
menu delete status
menu text status 50 5 Getting more cloth.
gosub cutupbolts
set %return #false
set %getbolts #true
wait %wait1
goto cloth
}
set %return #false
wait %wait1
goto cloth
}
return %return
}
set %getbone #false
leather:
if %bone . %currentitem = 0
set %leatheramt %maxweight - #weight - 10 - %used . %currentitem
gosub countresource %resource . %currentitem
if #result < %leather . %currentitem
{
if *522 <> IDLE && *522 <> Paused
goto leather
if %bone . %currentitem <> 0
{
gosub CalcItemAmounts
gosub CountBone
if #result >= %maxbone
gosub DumpBone
}
if %leatheramt < %leather . %currentitem
set %leatheramt %leather . %currentitem
menu delete status
menu text status 50 5 Getting more leather ( , %leatheramt , ).
gosub GetMoreResources %resource . %currentitem %leatheramt
set %getbone #true
if ! #result
{
gosub NeedMore Leather
menu delete status
menu text status 50 5 Getting more leather.
set %return #false
wait %wait1
goto leather
}
set %return #false
wait %wait1
goto leather
}
if %bone . %currentitem = 0
return %return
bones:
finditem %bonetypes c_ , %backpackID
if ( #findkind = -1 ) || ( #findkind <> -1 && #findstack < %bone . %currentitem ) || %getbone
{
gosub CalcItemAmounts
gosub CountBone
if #result >= %maxbone
gosub DumpBone
if %boneamt < %bone . %currentitem
set %boneamt %bone . %currentitem
menu delete status
menu text status 50 5 Getting more bones ( , %boneamt , ).
gosub GetMoreResources %bonetypes %boneamt
if ! #result
{
gosub NeedMore Bones
menu delete status
menu text status 50 5 Getting more bones.
wait %wait1
goto bones
}
set %return #false
wait %wait1
goto bones
}
return %return

sub CalcItemAmounts
set %leatherstack 0
set %bonestack 0
finditem %resource . %currentitem c_ , %backpackID
if #findkind <> -1
set %leatherstack #findstack
finditem %bonetypes c_ , %backpackID
if #findkind <> -1
set %bonestack #findstack
set %temp ( %maxweight - #weight  ) + %leatherstack + %bonestack
set %temp1 ( %temp ) - ( %temp / 3 )
set %boneamt ( ( ( %temp - %temp1 - 5 ) / 2 ) * 2 )
set %leatheramt ( %boneamt * 2 ) - %leatherstack
set %boneamt %boneamt - %bonestack
set %maxbone 5
return

sub GetMoreResources
; sub to get more resources, %1 resource, %2 amount
set %resourcetype %1
set %resourceamt %2
set *520 PAUSE
gosub WaitforPause
gosub ClearMenuGump
if %resourceamt < 1
set %resourceamt 1
GMR1:
finditem %resourcetype C
if #findkind <> -1
{
set %_findstack #findstack
set %_findid #findid
if #findbagid = %backpackid
{
ignoreitem #findid backpack
goto GMR1
}
if ( #findtype in %leathertypes && #findcol <> %lcolor . %leathertype ) || ( #findtype in %ironingots  && #findcol <> 0 ) || ( #findtype in %sewingkittypes && #findcol <> 0 )
{
ignoreitem #findid wrongcolor
goto GMR1
}
if #findstack < %resourceamt
set %resourceamt #findstack
finditem %backpackid C_ , #charid
if #findkind <> -1
{
set #findmod 140_220
set %backpackx #findx
set %backpacky #findy
event drag %_findid
wait %wait2
if %_findstack > 1
msg %resourceamt  $
wait %wait2
set %gmr2 0
GMR2:
click %backpackx %backpacky p
wait %wait1
if #contname = drag_gump
{
set %gmr2 %gmr2 + 1
menu font color yellow
menu delete status
menu text status 50 5 Drop on backpack, retrying ( , %gmr2 , ).
sound
wait %wait2
if %gmr2 < 3
{
gosub GetPaperDollXY
goto GMR2
}
display ok A problem occured trying to drop to your paperdoll's$
+backpack. Make sure the backpack icon is not blocked.$
+Press OK,  then drop the resource manually, correct$the problem and resume the script.$
gosub pause
menu font color lime
menu delete status
menu text status 50 5 Checking for more resources.
}
menu font color lime
set *520 CUT
ignoreitem reset backpack
set %retrycount 11
return #true
}
gosub GetPaperDollXY
menu delete pdwarning
gosub LocateTheDump
gosub CheckForBank
if ! #result
gosub GetSecureContainer
gosub GetResourceBag
goto GMR1
}
ignoreitem reset backpack
return #false

sub MaterialsToResource
; %1 = type , %2 = name
set %_MTRType %1
set %_MTRName %2
gosub ClearMenuGump
MTR1:
finditem %_MTRType C_ , %backpackid
if #findkind <> -1
{
set %_MTRfindid #findid
set %_MTRfindstack #findstack
str lower %_MTRName
menu delete status
menu text status 50 5 Moving #strres , #spc , to resource.
finditem %resourcebagid
set #findmod 25_7
if #findtype in %chesttypes
         set #findmod %chest_findmod
if #findkind <> -1
{
event drag %_MTRfindid
set %mtr2 0
MTR2:
wait %wait2
if %_MTRfindstack <> 1
msg $
if #contname = stack_gump
{
set %mtr2 %mtr2 + 1
wait %wait2
if %mtr2 < 3
goto MTR2
}
set %mtr3 0
MTR3:
wait %wait1
click #findx #findy p
wait %wait1
if #contname = drag_gump
{
set %mtr3 %mtr3 + 1
menu font color yellow
menu delete status
menu text status 50 5 Retrying #strres , #spc , to resource ( , %mtr3 , ).
sound
wait %wait2
if %mtr3 < 3
goto MTR3
display ok A problem is occuring trying to drop #strres on to$your resource container. Make sure the container is$
+not blocked. Press OK,  drop the #strres manually,$correct the problem and resume the script.$
gosub pause
}
menu font color lime
ignoreitem %_MTRfindid mtr
goto MTR1
}
ignoreitem reset mtr
return #false
}
ignoreitem reset mtr
return #true

sub WaitforPause
WaitforPause1:
set *520 pause
wait 5
if *522 <> PAUSED
goto WaitforPause1
wait %wait1
return

sub FindSewingKit
FSK1:
finditem  %sewingkittypes  C_ , %backpackID
if #findkind <> -1
{
set %sewkitid #findid
return
}
set *520 PAUSE
gosub WaitforPause
gosub GetMoreSewingKits
set *520 CUT
goto FSK1
return ; not needed

sub UseSewingKit
set *520 PAUSE
gosub WaitforPause
set #lobjectid %sewkitid
event macro 17 0
wait %wait1
set *520 CUT
return

sub MakeFirstItem
set %gumpx #contposx
set %gumpy #contposy
; %1 = category , %2 = selection
if %1 = 99
goto MFI1
wait %gumpwait
set %clickx %gumpx + 27
set %clicky %gumpy + 50 + ( %1 * 20 )
set %MF1_G 0
MF1_GumpWait:
wait %gumpwait
if #contname <> generic_gump
{
set %MF1_G %MF1_G + 1
if %MF1_G > 15
return #false
goto MF1_GumpWait
}
click %clickx %clicky f
if %slowconnection
wait %longwait
wait %wait2 %wait1
wait %wait1
if %2 = 99
return #true
set %mfi 0
MFI1:
wait %gumpwait
if #contname <> generic_gump
{
set %mfi %mfi + 1
if %mfi > 15
return #false
goto MFI1
}
set %gumpx #contposx
set %gumpy #contposy
MFI2:
if %2 = 98
{
set %clickx %gumpx + 385
set %clicky %gumpy + 270
goto MFI3
}
;set %clicky 100 + %2 * 20
set %clickx %gumpx + 235
set %clicky %gumpy + 50 + ( %2 * 20 )
MFI3:
click %clickx %clicky f
if %slowconnection
wait %longwait
wait %wait1 %wait1
return #true

sub GetMoreSewingKits
menu delete status
menu text status 50 5 Getting more sewing kits.
set %sewkits 0
GMSK1:
gosub GetMoreResources %sewingkittypes  1
if #result
{
set %sewkits %sewkits + 1
ignoreitem %sewkitid 1
if %sewkits >= %maxsewingkits
{
ignoreitem reset 1
return
}
goto GMSK1
}
if %sewkits = 0
{
gosub TinkerSewingKits
if #result > 0
{
ignoreitem reset 1
gosub ClearMenuGump
wait %wait2
return
}
gosub ClearMenuGump
gosub NeedMore sewingkits
ignoreitem reset 1
return
; goto GMSK1
}
ignoreitem reset 1
return

sub TinkerSewingKits
if %tinkerskill < %tinkerskillreq
return 0
set %retrycount 11
set %sewingkitsmade 0
set %makelasttinker #false
set #LOBJECTID n/a
for %i 1 %maxsewingkits
{
TSK1:
if #menubutton = pause
gosub pause
gosub CountTinkerKits
if ( #result = 0 ) || ( #result = 1 && %min_uses < 10 )
{
menu delete status
menu text status 50 5 Getting more Tinker's tools.
gosub GetMoreResources %tinkertools  1
if ! #result
{
gosub MakeTinkerTools
if ! #result
return %sewingkitsmade
}
set %makelasttinker #false
goto TSK1
}
gosub MakeSewingKit
if #result = -1
return %sewingkitsmade
if #result = 0
goto TSK1
set %i #result
set %sewingkitsmade %i
}
wait %wait1
return %sewingkitsmade

sub MakeTinkerTools
MTT1:
finditem %ironingots C_ , %backpackid
set %backpack_ingots #findstack
if #findkind = -1 || #findstack < 2
{
set %ingotamt 2 + (  ( %maxsewingkits - %sewingkitsmade ) * 2 ) - %backpack_ingots
menu delete status
menu text status 50 5 Getting more ingots ( , %ingotamt , ).
gosub GetMoreResources %ironingots %ingotamt
if ! #result
return #false
goto MTT1
}
menu delete status
menu text status 50 5 Tinkering Tinker's tools.
finditem %tinkertoolsid
if #findkind = -1
return #false
set %makelasttinker #false
set #LOBJECTID %tinkertoolsid
gosub WaitforPause
event macro 17 0
wait %longwait
gosub makefirstitem 3 4
wait %longwait
gosub CountTinkerKits
if #result < 2
goto MTT1
return #true

sub MakeSewingKit
set %_temp %sewingkitsmade + 1
menu delete status
menu text status 50 5 Tinkering sewing kit ( , %_temp , / , %maxsewingkits , ).
MSK1:
finditem %ironingots C_ , %backpackid
set %backpack_ingots #findstack
if #findkind = -1 || #findstack < 2
{
set %ingotamt  (  ( %maxsewingkits - %sewingkitsmade ) * 2 ) - %backpack_ingots
menu delete status
menu text status 50 5 Getting more ingots ( , %ingotamt , ).
gosub GetMoreResources %ironingots %ingotamt
if ! #result
return -1
goto MSK1
}
set %mst2 0
MST2:
set %mst2 %mst2 + 1
if %mst2 > 5
{
display ok Hmm, There appears to be a problem getting a tinker$
+menu to appear. No tinker tools? Something in the wrong place?$
+Please correct the problem. Pausing.
gosub pause
set %mst2 0
set %makelasttinker #false
set #LOBJECTID n/a
goto MST2
}
finditem %tinkertoolsid C_ , %backpackid
if #findkind = -1
return 0
gosub WaitforPause
if #lobjectid <> %tinkertoolsid
{
set #LOBJECTID %tinkertoolsid
event macro 17 0
wait %wait2
}
set %MST3 0
MST3:
if #contname <> generic_gump
{
if %mst3 > 10
{
set %makelasttinker #false
set #LOBJECTID n/a
goto MST2
}
set %mst3 %mst3 + 1
wait %gumpwait
goto MST3
}
wait %gumpwait
set %gumpx #contposx
set %gumpy #contposy
if  %makelasttinker
{
set %clickx %gumpx + %makelast_clickx
set %clicky %gumpy + %makelast_clicky
click %clickx %clicky f
goto MSK2
}
gosub makefirstitem 3 7
set %makelasttinker #true
MSK2:
wait %gumpwait
finditem %sewingkittypes  C_ , %backpackID
if #findkind <> -1
return #findcnt
return 0

sub ClearMenuGump
savePix 55 55 1
set %pixcol1 #pixcol
savePix 55 476 1
set %pixcol2 #pixcol
savePix 572 481 1
set %pixcol3 #pixcol
if %pixcol1 = 7568251 || %pixcol2 = 7568251 || %pixcol3 = 7568251
{
if %pixcol1 = 7568251
{
click 55 55 f ; bring the gump forward if it's not already
goto CMG2
}
if %pixcol2 = 7568251
{
click 55 476 f ; bring the gump forward if it's not already
goto CMG2
}
if %pixcol3 = 7568251
{
click 572 481 f ; bring the gump forward if it's not already
goto CMG2
}
}
set %waittime #scnt + 2
CMG1:
wait 5
if #contname <> generic_gump && %waittime > #scnt
goto CMG1
if #contname <> generic_gump
return
CMG2:
gosub makefirstitem 18 99
set %retrycount 11
wait %wait1
return

sub GetUsesRemaining
; %1 = #property
set %_1 %1
str pos %_1 :
set %temp #strres
str del %_1 1 %temp
set %_1 #strres
str pos %_1 $
set %temp #strres
str del %_1 %temp 1
return #strres

sub CountTinkerKits
set %ctk 0
set %min_uses 999
set %tinkertoolsid n/a
CTK1:
finditem %tinkertools C_ , %backpackid
if #findkind <> -1
{
set %_findid #findid
event property %_findid
wait 5
gosub GetUsesRemaining #property
if #result < %min_uses
{
set %min_uses #result
set %tinkertoolsid %_findid
}
ignoreitem #findid ctk
set %ctk %ctk + 1
goto CTK1
}
ignoreitem reset ctk
return %ctk

sub NeedMore
sound
menu font bgcolor red
menu font color black
menu delete status
str lower %1
menu text status 50 5 Need more #strres , #dot , #spc ,  Paused.
menu font bgcolor black
menu font color lime
if %sysmessages
event sysmessage Need more #strres , #dot , #spc ,  Paused.
set #menubutton pause
gosub pause
gosub LocateTheDump
gosub CheckForBank
if ! #result
gosub GetSecureContainer
gosub GetResourceBag
set %retrycount 11
return

sub FindJournalMessage
set %jc 1
FJM1:
scanjournal %jc
if #journal = N/A
return #false
for %_i 1 %0
{
if % . %_i in #journal
{
deletejournal
return #true
}
}
set %jc %jc + 1
goto FJM1

sub resetjournal
scanjournal 1
deletejournal
return

sub GetBackPackID
menu delete status
menu text status 50 5 Getting Backpack ID
gosub countscissors
if #result <> 1
goto GBPI1
finditem %scissortypes C
if #findkind <> -1
{
set %backpackid #findbagid
goto GBPI2
}
GBPI1:
gosub resetjournal
wait %wait2
event macro 8 7
wait %wait1
gosub FindJournalMessage must_wait
if #result || #contname <> container_gump
{
menu delete status
menu text status 50 5 Retrying backpack open.
wait %longwait
wait %longwait
goto GBPI1
}
set %backpackid #contid
GBPI2:
menu delete status
menu text status 50 5 Adjust your backpack now.
if %sysmessages
event SysMessage Adjust your backpack now, you have 5 seconds.
gosub waittimer 5
wait %longwait
menu delete status
return

sub countscissors
set %scissorcount 0
cs1:
finditem %scissortypes C
if #findkind <> -1
{
set %scissorcount  %scissorcount + 1
ignoreitem #findid scissors
goto cs1
}
ignoreitem reset scissors
return %scissorcount

sub GetPaperDollXY
gosub statusbarup
finditem %backpackid C_ , #charid
if #findkind <> -1
{
set #findmod 140_220
set %backpackx #findx
set %backpacky #findy
wait %longwait
return
}
event macro 8 1
menu delete status
menu text status 50 5 Adjust your paperdoll now.
gosub waittimer 5
menu font bgcolor red
menu font color black
menu text pdwarning 1 20 DON'T MOVE YOUR PAPERDOLL ANYMORE!
menu font bgcolor black
menu font color lime
menu delete status
menu text status 50 5 Getting Paperdoll Info
GPDXY1:
if #contname <> paperdoll_gump
{
gosub resetjournal
wait 5
wait %wait2
event macro 8 1
wait %wait1
gosub FindJournalMessage must_wait
if #result || #contname <> paperdoll_gump
{
menu delete status
menu text status 50 5 Retrying Paperdoll open.
wait %longwait
wait %longwait
goto GPDXY1
}
}
set %paperdollx #contposx
set %paperdolly #contposy
set %backpackx #contposx + 140
set %backpacky #contposy + 220
wait %longwait
return

sub GetResourceBag
GRB1:
if *525 <> N/A
{
set %resourcebagid *525
menu delete status
menu text status 50 5 Re-opening resource container.
wait 5
set %blinkmsg #true
goto GRB3
}
menu font color white
menu delete status
menu text status 50 5 Target your resource container now!
set %blinkmsg #true
set %blinktime #scnt2 + 5
;set #targcurs 1
;bring up a target
event macro 13 3
wait %wait1
if %sysmessages
event SysMessage Target your resource container now!
looptgt:
wait 3
if %blinktime < #scnt2
{
set %blinktime #scnt2 + 5
if %blinkmsg
{
menu delete status
set %blinkmsg #false
goto GRB2
}
menu text status 50 5 Target your resource container now!
set %blinkmsg #true
}
GRB2:
if #targcurs = 1
     goto looptgt

finditem #ltargetid C_ , %securecontainerid
if #findkind = -1
{
menu delete status
menu font color red
menu text status 50 5 Not in Secure/Bank Box. Try Again.
menu font color white
if %sysmessages
event SysMessage Not in Secure/Bank Box. Try Again.
wait 3s
display ok The resource bag must be inside a bank box or a secure box.$
+The bag you've identified is not in either one of these.$
+Please select a different bag.$$Script Paused.
gosub pause
;set #targcurs 1
;bring up a target
event macro 13 3
target 4s
wait %wait1
goto looptgt
}
GRB2B:
if #findtype notin %bagtypes
{
menu delete status
menu font color red
menu text status 50 5 Resource container type invalid ( , #findtype , ).
menu font color white
if %sysmessages
event SysMessage Resource container type invalid.
wait 3s
display ok The container type you have selected is a type that CEOTurboTailor$
+does not know. A regular chest or bag bought from the provisioners is$
+recommended. Please use a different type bag.$$Unknown Type: , #spc , #findtype $$Script Paused.
gosub pause
menu font color white
menu delete status
set %blinkmsg #false
;set #targcurs 1
;bring up a target
event macro 13 3
target 4s
wait %wait1
goto looptgt
}
set %resourcebagid  #ltargetid
GRB3:
finditem %resourcebagid C_ , %securecontainerid
set #findmod 25_7
if #findtype in %chesttypes
        set #findmod %chest_findmod
if #findkind = -1
{
menu delete status
menu font color red
menu text status 50 5 Resource container not found.
menu font color white
if %sysmessages
event SysMessage  Resource container not found.
wait 3s
set *525 N/A
goto GRB1
}
set *525 %resourcebagid
menu font color lime
set #lobjectid %resourcebagid
set %resourcex #findx
set %resourcey #findy
nextcpos %resource_bagx %resource_bagy
GRB4:
gosub resetjournal
wait %wait2
event macro 17 0
wait %wait1
gosub FindJournalMessage must_wait
if #result
{
menu delete status
menu text status 50 5 Retrying resource open.
if %sysmessages
event SysMessage Retrying resource open.
wait %longwait
wait %longwait
goto GRB4
}
menu delete status
menu text status 50 5 Adjust resource bag now.
if %sysmessages
event SysMessage Adjust resource bag now, you have 5 seconds.
gosub waittimer 5
wait %longwait
menu delete status
return

sub CheckForGain
if %currentskill = #skill
return
set %currentskill #skill
menu window color red
sound
menu delete status
menu text status 50 5 Tailor Gain!
gosub GainStats
wait 5
menu window color black
if %makeyourown
{
gosub gmcheck
return
}
gosub SelectItemToMake
set %newitem #result
set %lastcloth %cloth . %currentitem
if %currentitem <> %newitem
{
gosub skillchangedisplay
CFG1:
if *522 = CUTTING
{
wait 5
goto CFG1
}
set *520 PAUSE
gosub WaitforPause
set %currentitem %newitem
gosub RemoveNonEssentials
set %firstattempt #true
set *521 %product . %currentitem
gosub LocateTheDump
set %retrycount 11
}
gosub gmcheck
return

sub GMCheck
if ( ( #skill = %skillcap ) || ( %maxskillcap = #skill ) ) && ! %debug
{
set *520 cut
wait %wait1
set *520 pause
gosub WaitforPause
sound
if #contname = generic_gump
gosub ClearMenuGump
menu font color lime
menu delete making
menu text making 107 35 %desc10
sound
gosub MaterialsToResource %leathertypes leather
gosub MaterialsToResource %clothtypes cloth
gosub MaterialsToResource %bonetypes bone
sound
gosub MaterialsToResource %bandaids bandaids
gosub MaterialsToResource %sewingkittypes sewingkits
gosub MaterialsToResource %tinkertools tinkertools
gosub MaterialsToResource %ironingots ingots
sound
menu delete status
menu font color red
menu font bgcolor white
menu text status 50 5 Congratulations, skillcap reached!
if %maxskillcap = #skill
{
menu delete status
menu text status 50 5 Yahoo, maxskillcap reached!
}
sound
menu font style b
menu font align right
menu delete g1
menu text g1 100 246 #skill
menu font align left
set *520 done
menu font style n
menu font bgcolor black
menu font color lime
gosub DisplayElapsedTime
gosub floatgain
halt
}
return

sub HideMe
if ! %hideme || H in #charstatus
return #true
set %ht 0
set %retrycount 11
menu show
menu delete status
menu text status 50 5 Attempting to hide.
set *520 pause
wait %wait1
HM1:
event macro 13 21
wait %wait1
if H notin #charstatus && %ht < 5
{
set %ht %ht + 1
menu delete status
menu font color yellow
menu text status 50 5 Hiding failed! Retrying.. ( , %ht , )
menu font color lime
wait 12s
goto HM1
}
if H notin #charstatus
{
menu delete status
menu font color red
menu text status 50 5 Hiding failed, you suck at hiding.
menu font color lime
wait 12s
set *520 cut
return #false
}
menu delete status
menu text status 50 5 Hidden, waiting 12 seconds.
wait 12s
set *520 cut
return #true

sub initmenu
menu clear
menu window size 260 295
menu window title CEOTurboTailor %version
menu window color black
menu font bgcolor BLACK
menu font color red
menu show %menu_windowx %menu_windowy
menu font size 9
menu text hstatus 10 5 Status:
menu text h1 10 20 Elapsed Time:
menu text h1 10 35 Currently Making:
menu shape myshape1 3 53 254 1 3 7 5 blue 3 white
menu shape myshape1 3 173 254 1 3 7 5 blue 3 white
menu shape myshape1 3 263 254 1 3 7 5 blue 3 white
set #menubutton N/A
menu font size 11
menu font color white
menu font style ub
menu text h1 65 55 Resource Statistics
menu text h1 70 175 Tailoring Statistics
menu font size 9
menu font color fuchsia
menu font style b
menu font size 8
menu text h1 90 75 This
menu text h1 145 75 Last
menu font style bu
menu text h1 90 90 Gain
menu text h1 145 90 Gain
menu text h1 200 90 Total
menu font size 9
menu font color red
menu font style b
menu text h1 5 105 Attempts
menu text h1 5 120 Cloth
menu text h1 5 135 Leather
menu text h1 5 150 Bone
menu text h1 60 105 :
menu text h1 60 120 :
menu text h1 60 135 :
menu text h1 60 150 :
menu text h1 60 246 :
menu text h1 5 200 Last gain at:
menu font size 8
menu font color fuchsia
menu font align right
menu text h1 100 215 Total
menu text h1 160 215 Current
menu text h1 220 215 Gain
menu font style bu
menu text h2  100 230 Skill
menu text h2  160 230 Gains
menu text h2  220 230  Rate
menu font style b
menu font align left
menu font color red
menu font size 9
menu text h3 10 246 Tailoring
menu font color lime
menu font style n
if %firstmenu
gosub GainStats
menu font align left
gosub DisplayElapsedTime
menu font align right
menu text a3 225 105 %attempts3
menu text c3 225 120 %clothused3
menu text l3 225 135 %leatherused3
menu text b3 225 150 %boneused3
menu font align left
menu font color white
menu font style u
menu text h1 5 215 Skillcap
menu text h1 7 70 Est. Cost
menu font style n
menu text h1 60 85 gp
menu font align right
gosub calctotalcosts
menu font align left
if %maxskillcap = N/A
menu text skillcap 13 230 %skillcap
else
menu text skillcap 2 230 %skillcap , ( , %maxskillcap , )
menu font color lime
menu text making 107 35 %desc . %currentitem
menu font bgcolor teal
menu font color black
menu button pause 100 270 60 20 Pause
menu button hide 5 270 60 20 Hide
menu button makeyourown 190 270 65 20 Make Item
menu button resetstats 215 60 40 20 Reset
menu button SkillChart 235 180 20 15 SC
;halt
if ! %debug
menu hideeuo
menu show %menu_windowx %menu_windowy
menu font bgcolor black
menu font color lime
set %firstmenu #false
return

sub calctotalcosts
menu font color yellow
set %tcosts %clothused3 * %cost_of_cloth + %leatherused3 * %cost_of_leather + %boneused3 * %cost_of_bone
menu delete tcost
menu text tcost 55 85 %tcosts
menu font color lime
return

sub ResetStats
set #menubutton N/A
Display YesNo Are you sure you want to erase all statistics and start over?
if #dispres = no
return
set %_530 0
set %attempts 0
for %i 1 3
{
set %attempts . %i 0
set %clothused . %i 0
set %leatherused . %i 0
set %boneused . %i 0
menu delete a . %i
menu delete c . %i
menu delete l . %i
menu delete b . %1
}
;reset Globals
set *523 %currentskill
set *526 0
set *527 0
set *528 0
set *529 0
set *530 0
gosub redrawstats
menu font align right
gosub calctotalcosts
menu font align left
return


sub floatgain
menu delete pause
menu delete hide
menu delete makeyourown
menu delete resetstats
menu delete SkillChart
menu font style n
menu font bgcolor teal
menu font color black
menu button closed 100 270 60 20 Exit
set #menubutton N/A
menu font color lime
menu font size 25
menu font bgcolor black
gm1:
set %x #random % 269
set %y #random % 295
set %c1 #random % 255
set %c2 #random % 255
set %c3 #random % 255
menu font color %c1 , %c2 , %c3
set %c1 #random % 255
set %c2 #random % 255
set %c3 #random % 255
menu font bgcolor %c1 , %c2 , %c3
set %c1 #random % 255
set %c2 #random % 255
set %c3 #random % 255
menu window color %c1 , %c2 , %c3
set %c1 #random % 30 + 10
menu font size %c1
menu delete gm
menu text gm %x %y #skill
wait 3
if #menubutton = closed || *520 = terminate
{
set *520 terminate
terminate euo
}
goto gm1

sub DisplayElapsedTime
menu show
set %elaspedtime #scnt - %scriptstart
set %totaletime %_530 +  %elaspedtime
set *530 %totaletime
set %ehours %totaletime / 3600
set %emins  ( %totaletime / 60 ) - ( %ehours * 60 )
menu font color white
if %lastehours <> %ehours
{
set %lastehours %ehours
menu delete ehours
menu text ehours 95 20 %ehours , h
}
if %lastemins <> %emins
{
set %lastemins %emins
menu delete emins
menu text emins 120 20 %emins , m
}
menu font color lime
return ; remove this you want seconds display
menu font color white
set %esecs %totaletime % 60
if %lastesecs <> %esecs
{
set %lastesecs %esecs
menu delete esecs
menu text esecs 150 20 %esecs , s
}
menu font color lime
return


sub GainStats
menu delete g1
menu delete g2
menu delete g3
set %tailorgain #skill - %startskill
set %time X , #time
set %time1 #scnt
set %rate %tailorgain * 3600 / ( #scnt - %scriptstart  )
menu font align right
menu text g1 100 246 #skill
menu text g2 160 246 %tailorgain
menu text g3 220 246 %rate
menu font align left
set %unhidecount 0
set %attempts2 %attempts1
set %attempts1 0
set %clothused2 %clothused1
set %clothused1 0
set %leatherused2 %leatherused1
set %leatherused1 0
set %boneused2 %boneused1
set %boneused1 0
menu font align right
for %i 1 2
{
menu delete a . %i
menu delete c . %i
menu delete l . %i
menu delete b . %i
}
menu text a1 113 105 %attempts1
menu text c1 113 120 %clothused1
menu text l1 113 135 %leatherused1
menu text b1 113 150 %boneused1
menu text a2 168 105 %attempts2
menu text c2 168 120 %clothused2
menu text l2 168 135 %leatherused2
menu text b2 168 150 %boneused2
menu font align left
if %startskill <> %currentskill
{
gosub FormatTime %time
menu delete time
menu text time 77 200 #result
set %egain %time1 - %gaintime
set %eghours %egain / 3600
set %egmins  ( %egain / 60 ) - ( %eghours * 60 )
set %egsecs %egain % 60
menu delete time2
menu text time2 130 200 ( , %eghours , h , #spc , %egmins , m , #spc , %egsecs , s , #spc , used)
set %gaintime %time1
}
return

sub DisplayResourceStats
set %attempts1 %attempts1 + 1
set %unhidecount %unhidecount + 1
set %attempts3 %attempts3 + 1
menu font align right
menu delete a1
menu delete a3
menu text a1 113 105 %attempts1
menu text a3 225 105 %attempts3
set *526 %attempts3
if %cloth . %currentitem <> 0
{
set %clothused1 %clothused1 + %used . %currentitem
set %clothused3 %clothused3 + %used . %currentitem
set *527 %clothused3
menu delete c1
menu delete c3
menu text c1 113 120 %clothused1
menu text c3 225 120 %clothused3
}
if %leather . %currentitem <> 0
{
set %leatherused1 %leatherused1 + %used . %currentitem
set %leatherused3 %leatherused3 + %used . %currentitem
set *528 %leatherused3
menu delete l1
menu delete l3
menu text l1 113 135 %leatherused1
menu text l3 225 135 %leatherused3
}
if %bone . %currentitem <> 0
{
set %boneused1 %boneused1 + %bone . %currentitem
set %boneused3 %boneused3 + %bone . %currentitem
set *529 %boneused3
menu delete b1
menu delete b3
menu text b1 113 150 %boneused1
menu text b3 225 150 %boneused3
}
gosub calctotalcosts
menu font align left
if %hideme &&  H in #charstatus && %unhidecount > %unhideat
{
menu delete status
menu text status 50 5 Unhiding due to no gains.
gosub WaitforPause
set %rnd ( #random % 5 ) + 1
str mid %unhidetext %rnd 1
event macro 3 1 #strres
set %unhidecount 0
}
return

sub FormatTime
str ins %1 : 4
set %1 #strres
str ins %1 : 7
set %1 #strres
str del %1 1 1
set %1 #strres
return %1

sub hide
set %hideme #true
set #menubutton N/A
return

sub Pause
sound
;menu window color gray
menu font transparent #true
menu font size 30
menu font color red
menu font style b
menu text  ptext  62 120 Paused
menu font size 9
menu font style n
menu font color lime
menu font transparent #false
if %sysmessages
{
event sysmessage Paused. Press the resume button or toggle out
event sysmessage of warmode. If not in warmode, toggle to war/peace.
}
set %returnbywarmode #false
if G in #charstatus
{
menu delete status
menu font color yellow
menu text status 50 5 Paused via warmode.
menu font color green
set %returnbywarmode #true
}
menu delete pause
menu font bgcolor teal
menu font color black
menu button resume 100 270 60 20 Resume
gosub WaitforPause
set #menubutton N/A
Pause1:
if G in #charstatus
set %returnbywarmode #true
if %returnbywarmode && G notin #charstatus
      set #menubutton resume
wait 5
if #menubutton = N/A
goto Pause1
menu delete ptext
if #menubutton = closed
gosub closed
menu delete resume
menu button pause 100 270 60 20 Pause
set #menubutton N/A
set %retrycount 11
menu window color black
menu font bgcolor black
menu font color lime
return

sub closed
set %elaspedtime #scnt - %scriptstart
set %totaletime %_530 +  %elaspedtime
set *530 %totaletime
if %exitonclose && ! %debug
{
set *520 terminate
terminate euo
}
set #menubutton N/A
return

sub AutoSetup
gosub gmcheck
if %hideme = N/A && %hideskill > %hideskillreq
set %hideme #true
if %hideme = N/A
set %hideme #false
menu show
gosub GetBackPackID
menu show
gosub GetPaperDollXY
menu show
menu delete pdwarning
set %maxweight #maxweight - ( %maxsewingkits * 2 )
if %maxweight > 405
set %maxweight 405 - ( %maxsewingkits * 2 )
if %bankfound = N/A
{
gosub checkforbank2
set %bankfound #result
}
if *524 = N/A || *524 = bank || %bankfound
gosub CheckForBank
menu show
if ! #result
gosub GetSecureContainer
gosub GetResourceBag
menu show
gosub LocateTheDump
gosub CheckforMultipleCloths
return

sub LocateTheDump
if %bone . %currentitem <> 0
{
if *524 <> bank
gosub FindDumpster

if *524 = bank
gosub FindTrashCan 12
}
return


sub CountBone
set %cbh 0
CBH1:
finditem %product . %currentitem C_ , %backpackid
if #findkind <> -1
{
set %cbh %cbh + 1
ignoreitem #findid bone
goto CBH1
}
ignoreitem reset bone
return %cbh

sub DumpBone
wait %wait2
if *524 <> bank
{
gosub FindDumpster
nextcpos %trash_barrelx %trash_barrely
set #lobjectid %trashcanid
wait %wait2
event macro 17 0
wait %longwait
contpos %trash_barrelx %trash_barrely
wait %wait1
set %trash_clickx  %trash_barrelx + 30
set %trash_clicky %trash_barrely + 160
gosub MoveBonestoTrash
}
if *524 = bank
{
set %charposx #charposx
set %charposy #charposy
gosub FindTrashCan 12
move #findx #findy 2 4s
gosub FindTrashCan 2
nextcpos %trash_barrelx %trash_barrely
set #lobjectid %trashcanid
wait %wait2
event macro 17 0
wait %longwait
contpos %trash_barrelx %trash_barrely
wait %wait1
set %trash_clickx  %trash_barrelx + 90
set %trash_clicky %trash_barrely + 150
gosub MoveBonestoTrash
move %charposx %charposy 0 4s
gosub CheckForBank
gosub GetResourceBag
}
return

sub MoveBonestoTrash
set %ba1 0
gosub resetjournal
MBT1:
wait 5 10
finditem %product . %currentitem C_ , %backpackid
;finditem ZLF C_ , %backpackid ; testline so I don't have to really use bone...
if #findkind <> -1
{
set %ba1 %ba1 + 1
menu delete status
menu text status 50 5 Dumping bone armor ( , %ba1 , ).
event drag #findid
set %mbt2 0
MBT2:
wait %wait1
click %trash_clickx %trash_clicky p
wait %wait1
if #lliftedkind <> 0
{
set %mbt2 %mbt2 + 1
if %mbt2 > 3
{
if %mbt2 > 9
{
menu delete status
menu text status 50 5 Aborting dump.
display ok There is a problem transferring items to your trashcan.$You will need to do it manually.$Pausing script.$
gosub pause
return
}
menu delete status
menu text status 50 5 Dump Problems, Trying again...
set #lobjectid %trashcanid
event macro 17 0
contpos %trash_barrelx %trash_barrely
goto MBT2
}
goto MBT2
}
wait %wait1
set %mbt2 0
goto MBT1
}
return


sub FindDumpster
FD1:
menu delete status
menu text status 50 5 Locating dumpster.
set %trash_clickx 0
set %trash_clicky 0
finditem %trashbarreltype G_2
if #findkind <> -1
{
set %trashcanid #findid
return #true
}
gosub NoDumpster
goto FD1
return #false


sub NoDumpster
sound
menu font bgcolor red
menu font color black
menu delete status
menu text status 50 5 You're not near a trash barrel!
menu font bgcolor black
menu font color lime
set #menubutton pause
gosub pause
return

sub FindTrashCan
set %_distance %1
FTC1:
menu delete status
menu text status 50 5 Locating trashcan.
set %trashx 0
set %trashy 0
finditem %bankgarbage G_ , %_distance
if #findkind <> -1
{
set %trashcanid #findid
return #true
}
gosub NoTrashCan
goto FTC1
return #false


sub NoTrashCan
sound
menu font bgcolor red
menu font color black
menu delete status
menu text status 50 5 You're not near a Bank Trash Can!
menu font bgcolor black
menu font color lime
set #menubutton pause
gosub pause
return

sub CheckforBank2
set %housesigns GNE_INE_SNE_UNE_ONE_QNE_AOE_QJE_
+COE_WNE_YNE_IOE_KOE_EOE_GOE_SJE_UJE_OJE_AKE_
+CKE_WJE_YJE_IKE_KKE_EKE_GKE_QKE_SKE_MKE_OKE_
+YKE_ALE_UKE_WKE_GLE_ILE_CLE_ELE_OLE_QLE_KLE_
+MLE_WLE_YLE_SLE_ULE_CRE_ERE_YQE_ARE_KRE_MRE_
+GRE_IRE_LRE_HKE_XJE
CFB12:
finditem %housesigns
if #findkind <> -1
{
event property #findid
wait 5
if bank in #property || mint in #property
return #true
ignoreitem #findid bankcheck
goto CFB12
}
set %pc 0
CFB22:
finditem HS_IS
if #findkind <> -1
{
set %pc %pc + 1
if #findrep = 7
{
event property #findid
if banker in #property || minter in #property
return #true
ignoreitem #findid bankcheck
goto CFB22
}
ignoreitem #findid bankcheck
goto CFB22
}
if %pc > 10
return #true
return #false


sub CheckForBank
if ! %bankfound
return #false
menu delete status
menu text status 50 5 Checking for bank.
wait 5
gosub resetjournal
CFB1:
nextcpos %bank_securex %bank_securey
msg Guards! Guards! Open the Bank please!$
wait %longwait
gosub FindJournalMessage Bank_Container
if #result
{
set *524 bank
menu delete status
menu text status 50 5 Looks like you're at a bank.
contpos %bank_securex %bank_securey
wait %wait1
set %securecontainerid N/A
if #contsize = 180_240
{
set %securecontainerid #contid
}
if %securecontainerid = N/A
goto CFB1
menu delete status
menu text status 50 5 Adjust your bank box now.
if %sysmessages
event SysMessage Adjust your bank box now, you have 5 seconds.
gosub waittimer 5
menu delete status
return #true
}
return #false

sub GetSecureContainer
GSC1:
if *524 <> N/A && *524 <> bank
{
set %securecontainerid *524
menu delete status
menu text status 50 5 Re-opening secure container.
wait 5
set %blinkmsg #true
goto GSC3
}
set *525 N/A
menu font color white
menu delete status
menu text status 50 5 Target your SECURE container now!
set %blinkmsg #true
set %blinktime #scnt2 + 5
;set #targcurs 1
;bring up a target
event macro 13 3
target 4s
wait %wait1
if %sysmessages
event SysMessage Target your SECURE container now!
looptgt2:
wait 3
if %blinktime < #scnt2
{
set %blinktime #scnt2 + 5
if %blinkmsg
{
menu delete status
set %blinkmsg #false
goto GSC2
}
menu text status 50 5 Target your SECURE container now!
set %blinkmsg #true
}
GSC2:
if #targcurs = 1
     goto looptgt2
finditem #ltargetid G_2
if #findtype notin %bagtypes
{
menu font color red
menu delete status
menu text status 50 5 Invalid container type. Try Again.
menu font color white
if %sysmessages
event SysMessage Invalid container type. Try Again.
wait 3s
display ok The container type you have selected is a type that CEOTurboTailor$
+does not know. A regular chest or bag bought from the provisioners is$
+recommended. Please use a different type bag.$$Unknown Type: , #spc , #findtype $$Script Paused.
gosub pause
;set #targcurs 1
;bring up a target
event macro 13 3
target 4s
wait %wait1
goto looptgt2
}
set %securecontainerid  #ltargetid
GSC3:
finditem %securecontainerid G_2
if #findkind = -1
{
menu font color red
menu delete status
menu text status 50 5 SECURE container not found.
menu font color white
if %sysmessages
event SysMessage SECURE container not found.
wait 3s
set *524 N/A
goto GSC1
}
set *524 %securecontainerid
menu font color lime
nextcpos %bank_securex %bank_securey
set #lobjectid %securecontainerid
GSC4:
gosub resetjournal
wait %wait2
event macro 17 0
wait %wait1
gosub FindJournalMessage must_wait
if #result
{
menu delete status
menu text status 50 5 Retrying Secure box open.
if %sysmessages
event SysMessage Retrying Secure box open.
wait %wait2
wait %longwait
goto GSC4
}
contpos %bank_securex %bank_securey
menu delete status
menu text status 50 5 Adjust secure bag now.
if %sysmessages
event SysMessage Adjust secure bag now, you have 5 seconds.
gosub waittimer 5
menu delete status
wait %longwait
return

sub makeyourown
MYO0:
display yesno Using this option will allow you to make your first item and then$
+the script will Make Last until you stop it  or select the Make Item$
+button again. Do you want to continue?$$
+Yes=Make Item, No=Use Skill Chart
if #dispres = NO
{
set %retrycount 11
set #menubutton N/A
gosub SelectItemToMake
set %currentitem #result
gosub RemoveNonEssentials
set %firstattempt #true
set %makeyourown #false
set %leathertype %defaultleathertype
set *520 cut
return
}
set %packcloth 0
set %packleather 0
set %packbone 0
set %cloth99 0
set %leather99 0
set %bone99 0
gosub FindSewingKit
gosub UseSewingKit
set *520 pause
gosub WaitforPause
menu delete status
menu text status 50 5 Examining backpack contents.
MYO1:
finditem * C_ , %backpackid
if #findkind <> -1
{
if #findtype in %clothtypes
set %packcloth #findstack
if #findtype in %leathertypes
set %packleather #findstack
if #findtype in %bonetypes
set %packbone #findstack
ignoreitem #findid backpack
goto MYO1
}
MYO2:
menu font bgcolor blue
menu font color white
menu delete status
menu text status 50 5 Make your item now.
wait 5
finditem * C_ , %backpackid
if #findkind = -1
{
menu font bgcolor white
menu font color blue
menu delete status
menu text status 50 5 Make your item now.
wait 5
goto MYO2
}
menu font bgcolor black
menu font color lime
menu delete status
menu text status 50 5 New item detected.
set %product99 #findtype
event property #findid
;what got used?
ignoreitem reset backpack
if %packcloth <> 0
{
finditem %clothtypes C_ , %backpackid
if #findkind = -1
{
set %cloth99 %packcloth
set %resource99 %clothtypes
goto MYO3
}
if #findstack <> %packcloth
{
set %cloth99 %packcloth - #findstack
set %resource99 %clothtypes
goto MYO3
}
}
if %packleather <> 0
{
finditem %leathertypes  C_ , %backpackid
if #findkind = -1
{
set %leather99 %packleather
set %resource99 %leathertypes
set %_myocolor #findcol
goto MYO2b
}
if #findstack <> %packleather
{
set %leather99 %packleather - #findstack
set %resource99 %leathertypes
set %_myocolor #findcol
}
}
MYO2b:
if %packbone <> 0
{
finditem %bonetypes  C_ , %backpackid
if #findkind = -1
set %bone99 %packbone
if #findstack <> %packbone
set %bone99 %packbone - #findstack
}
MYO3:
; now cut it up
if ( %product99 in %invalidtypes )
{
display ok Invalid type. $$This item can not be cut up properly!
goto MYO0
}
gosub resetjournal
set *521 %product99
set *520 cut
wait %longwait
set *520 pause
gosub WaitforPause
wait %longwait
gosub FindJournalMessage Scissors_Cannot
if ( #result && %bone99 = 0 )
{
if %product99 notin %invalidtypes
set %invalidtypes %invalidtypes , %product99 , _
display ok Invalid type. $$This item can not be cut up properly$and is not a bone type armor!
goto MYO0
}
set %used99 0
if %packcloth <> 0
{
finditem %clothtypes C_ , %backpackid
if #findstack <> %packcloth
set %used99 %packcloth - #findstack
}
if %packleather <> 0
{
finditem %leathertypes  C_ , %backpackid
if #findstack <> %packcloth
set %used99 %packleather - #findstack
}
if %used99 <= 0
{
display ok Hmm, something did not work right.$No resources or a negative amount were used!$Try again.
goto MYO0
}
str pos #property $
set %temp #strres - 1
str left #property %temp
set %desc99 #strres
if exceptional in %desc99
{
str del %desc99 1 12
set %desc99 #strres
}
display YesNo Is this correct? $ , %desc99 $Cloth: %cloth99 $Leather: %leather99 $Bone: %bone99 $Used: %used99 $
if #dispres = no
goto MYO0
set %currentitem 99
gosub RemoveNonEssentials
set %makeyourown #true
set %firstattempt #true
set #menubutton N/A
set %leathertype %defaultleathertype
if %leather99 <> 0
{
for %_i 1 4
{
if %lcolor . %_i = %_myocolor
set %leathertype %_i
}
}
set *520 cut
return

sub RemoveNonEssentials
if %leather . %currentitem = 0
gosub MaterialsToResource %leathertypes leather
if %cloth . %currentitem = 0
gosub MaterialsToResource %clothtypes cloth
gosub MaterialsToResource %bandaids bandaids
if %bone . %currentitem <> 0
{
gosub CountBone
if #result <> 0
gosub DumpBone
}
return


sub SetUpSkills
chooseskill hiding
set %hideskill #skill
chooseskill tinkering
wait %wait1
set %tinkerskill #skill
chooseskill tail
if #skillLock <> up
{
menu delete status
menu text status 50 5 Setting Tailoring skill up.
display ok Your tailoring skill is down! $Pointless to run this script don't you think?$
}
if #skill < 125
{
menu delete status
menu text status 50 5 Go buy some tailoring skill!
menu hideeuo
display ok This script requires that you go buy your tailoring$skill up to at least 12.5 or train manually.$$
+Please do so and restart the script, thank you.
menu hide
sound
halt
}
if *523 = N/A
set *523 #skill
wait %wait1
set %startskill #skill
set %currentskill #skill
set %skillcap #skillcap
if ( #skillcap <> 1000 ) && ( #skillcap <> 1050 ) && ( #skillcap <> 1100 ) && ( #skillcap <> 1150 ) && ( #skillcap <> 1200 )
gosub Tailor_1000
else
gosub Tailor_ , #skillcap
gosub SelectItemToMake
set %currentitem #result
;
;
set %desc1 Doublets
set %resource1 %clothtypes
set %cloth1 8
set %leather1 0
set %bone1 0
set %used1 7
set %product1 XVL
set %category1 4
set %selection1 1
;
set %desc2 plain , #spc , dresses
set %resource2 %clothtypes
set %cloth2 10
set %leather2 0
set %bone2 0
set %used2 5
set %product2 DWL
set %category2 4
set %selection2 6
;
set %desc3  fancy , #spc , dresses
set %resource3 %clothtypes
set %cloth3 12
set %leather3 0
set %bone3 0
set %used3 6
set %product3 VQL
set %category3 4
set %selection3 7
;
set %desc4 cloaks
set %resource4 %clothtypes
set %cloth4 14
set %leather4 0
set %bone4 0
set %used4 7
set %product4 DCI
set %category4 4
set %selection4 8
;
set %desc5 robes
set %resource5 %clothtypes
set %cloth5 16
set %leather5 0
set %bone5 0
set %used5 8
set %product5 FWL
set %category5 4
set %selection5 9
;
set %desc6 Oil , #spc , Cloth
set %resource6 %clothtypes
set %cloth6 1
set %leather6 0
set %bone6 0
set %product6 %oilcloth
set %used6 1
set %category6 6
set %selection6 4
if %uose_menu
set %selection6 5
;
set %desc7 Studded , #spc , gorget
set %resource7 %leathertypes
set %cloth7 0
set %leather7 6
set %bone7 0
set %used7 3
set %product7 ALH
set %category7 9
set %selection7 1
;
set %desc8 Studded , #spc , gloves
set %resource8 %leathertypes
set %cloth8 0
set %leather8 8
set %bone8 0
set %product8 XKH
set %used8 4
set %category8 9
set %selection8 2
;
set %desc10 Lady, , #spc , you , #spc , are , #spc , done!
if #sex = 0
set %desc10 Lord, , #spc , you , #spc , are , #spc , done!
set %cloth10 100000
if %makebone
{
set %desc9 Bone , #spc , Helmet
set %resource9 %leathertypes
set %cloth9 0
set %leather9 4
set %bone9 2
set %product9 YPH
set %used9 4
set %category9 11
set %selection9 1
return
}
;
set %desc9 Studded , #spc , Sleeves
set %resource9 %leathertypes
set %cloth9 0
set %leather9 10
set %bone9 0
set %product9 YKH
set %used9 5
set %category9 9
set %selection9 3
return

sub SelectItemToMake
set %itemtomake 0
for %i 1 9
{
if %currentskill >=  %switchpoint . %i
set %itemtomake %i
}
set %itemtomake %itemtomake + 1
return %itemtomake

sub Tailor_1000
set %switchpoint1 124
set %switchpoint2 331
set %switchpoint3 414
set %switchpoint4 539
set %switchpoint5 746
set %switchpoint6 996
set %switchpoint7 1039
set %switchpoint8 1079
set %switchpoint9 1100
return

sub Tailor_1050
set %switchpoint1 124
set %switchpoint2 331
set %switchpoint3 414
set %switchpoint4 539
set %switchpoint5 746
set %switchpoint6 1021
set %switchpoint7 1063
set %switchpoint8 1104
set %switchpoint9 1125
return

sub Tailor_1100
set %switchpoint1 124
set %switchpoint2 331
set %switchpoint3 414
set %switchpoint4 539
set %switchpoint5 746
set %switchpoint6 1046
set %switchpoint7 1088
set %switchpoint8 1129
set %switchpoint9 1150
return

sub Tailor_1150
set %switchpoint1 124
set %switchpoint2 331
set %switchpoint3 414
set %switchpoint4 539
set %switchpoint5 746
set %switchpoint6 1071
set %switchpoint7 1113
set %switchpoint8 1154
set %switchpoint9 1175
return

sub Tailor_1200
set %switchpoint1 124
set %switchpoint2 331
set %switchpoint3 414
set %switchpoint4 539
set %switchpoint5 746
set %switchpoint6 1096
set %switchpoint7 1138
set %switchpoint8 1179
set %switchpoint9 1201
return

sub StatusBarUp
;purpose - make sure the status bar is up on the char
IF #charname = N/A
{
Event Macro 8 2
wait %wait2
}
return

sub SkillChart
menu clear
menu window size 350 260
menu wind

[Tvvizag]

Это скрипт на тейлоринг?!?!?!?!?!?

БОльше похожу на программу для захвата космического спутника-шпиона  

[TAR]

Я тут вернулся немного пьяный но со скриптом немного разобрался.
мде правильно скрит конечно как на запуск спутника-шпиона
особо копаться щас не в состоянии но имхо в конце скрипта

sub Tailor_1200
set %switchpoint1 124
set %switchpoint2 331
set %switchpoint3 414
set %switchpoint4 539
set %switchpoint5 746
set %switchpoint6 1096
set %switchpoint7 1138
set %switchpoint8 1179
set %switchpoint9 1201
return

при скиллкапе 1200 измени на

sub Tailor_1200
set %switchpoint1 124
set %switchpoint2 331
set %switchpoint3 414
set %switchpoint4 539
set %switchpoint5 746
set %switchpoint6 1201
return

или на

sub Tailor_1200
set %switchpoint1 124
set %switchpoint2 331
set %switchpoint3 414
set %switchpoint4 539
set %switchpoint5 746
set %switchpoint6 1096
set %switchpoint7 1201
return

не знаю на каком скилле он переходит с тряпок на кожу...

при другом скиллкапе меняй не столбик 1200 а другой.

по идее он не должен переходить с ткани
если скажешь точнее какой скиллкап у тебя и на каком скилле он с ткани ушел на кожу скажу точнее.

ну если щас есть ктонить более трезвый пусть меня поправят

[Skywalker]

Он при скилле 99.6 уходит с ткани на кожу.
Т.е. просто заменить столбики?
И до сколько качаться на ткани? Я слышал, что приэтом надо съесть ПС на 120?

[TAR]

Такс на 99.6 он уходит на кожу тока при капе 100

до каких качаться на ткани это спрашивай у когонить другого
если сожрать ПС 120 и заменить последний столбик на

sub Tailor_1200
set %switchpoint1 124
set %switchpoint2 331
set %switchpoint3 414
set %switchpoint4 539
set %switchpoint5 746
set %switchpoint6 1201
return

то он будет идти на ткане до 120.

[Skywalker]

Пасиб

[Skywalker]

Хоть америкосы типо умные, русские умней. Мы лохи.
Там внизу есть строчки:
;what to make according to skillcap, posted by wvultig
;100 105 110 115 120
;099.6 102.1 104.6 107.1 109.6 Oil Cloth 1 Cloth
;103.8 106.3 108.8 111.3 113.8 Studded gorget 6 Hides;107.9 110.4 112.9 115.4 117.9 Studded gloves 8 Hides
;110.0 112.5 115.0 117.5 120.0 Bone Helmet 4 Hides+2 Bones
;112.1 114.6 117.1 119.6 122.1 Studded Armor (Female) 10 Hides
;112.1 114.6 117.1 119.6 122.1 Studded sleeves 10 Hides


просто заменяешь Studded gorget 6 Hides на Oil Cloth 1 Cloth и он тебе качает на оил колс


П.с. Поставьте топик в FAQ

[Brikobrak-~]

Skywalker (24.07.2005 20:02) писал:

П.с. Поставьте топик в FAQ

Нафига этот бред в  FAQ......
Топик даже не о том что ты не разбираешься в скриптах Изи (я тоже не разбираюсь) а о том, что тебе даже лень прочитать мануал для скрипта.

Все там отлично работает и работало всегда, если руки откуда надо растут.

[Rarst alSava]

Извращенцы. ЦЕОтейлор сам подстраивается под долбанный скилкап и шьет тряпки до того момента до которого они гейнят в зависимости от съеденного скрола. И уж тем более редактирование комментария функциональность скрипта не изменит.

Так что какой FAQ, стирать надо эту ересь. В самом начале ответил же что надо делать - выбрать нужную схему и всё.

[Skywalker]

****Удалено****
Ну не знал.

Брикобарик, респект, так держать!

см.подпись.

[Rarst alSava]

Смайлики не зря натыканы, так что не надо так огрызатся сходу. Была ыбы жельчь, там другие эмоты бы стояли, да?

Тебе асболютно с добром в течении девяти минут после вопроса был дан абсолютно точный и исчерппывающий ответ. А вы тут пошли таким маятся. ))

[Skywalker]

Раст Да ты что?! не  тебе же я. Всем вам, тебе, - огромное спасибо за помощь, правда.

Я другому субъекту

[Rarst alSava]

А ну тогда проехали. Шло сразу за моим постом с призывами жечь ересь, принял на свой счет.

[Skywalker]

Просто ты успел первей тыкнуть на кнопку, пока я *плакалЬ* =)

[Brikobrak-~]

Ппц новис пошел, хлипкий да нежный.

Mondzeer'а на вас блин нету.