0
Кач на вскрытии сундуков в бекпаке дает рост, однако на уровне 50 рост в 1.8% в час (в среднем) сначала пугает, потом плакать хочется.
Так вот - есть замечательное место рядом с Yew. Называется Yew Crypt. Там такие реалии: лезем в него, спускаемся на -2-й этаж, бегаем и поднимаемся в другом месте (их несколько, нам все равно в каком именно). Вы окажетесь в комнате, из которой нет выхода на поверхность, зато двери ведут в комнату, в которой в произвольном порядке происходит респ сундуков. При попытке вскрыть сундук скорее всего у Вас ничего не получится... да и к тому же, в среднем 1 раз из 5 попыток вызывает потерю локпика. Но зато! Локпикинг... растет и растет не слабо. У меня локпикинг пророс на 10 за... два часа что ли (с 69+ до 80+)... В связи с этим на изиуо есть скрипт, который пытается не только вскрыть сундук, но и еще поюзать открытый... я кастрировал (награда там тоже смешная).
;==================================
; Script Name: Yew Lockpicking
; Author: Bigguy/Dumpy
; Version: 1.7
; Client Tested with: 4.0.1d
; EUO version tested with: 1.41
; Shard OSI / FS: OSI/Baja
; Revision Date: 07-16-2004
; Public Release: 02-24-2004
; Global Variables Used: None
; Purpose: Pick chests in south yew crypts room. Hides while waiting for spawned chests
;
; Revisions
; 1.5 - Dumpy - Modified Hiding section. Hiding is now optional.
; Added option to use Invis instead (or use neither)
; see
; Note: Hiding will take precedence over invis if both are set
;
; Added option to not move to corner (hide/invis where you're at after looting)
; Note: Moving to corner will cause several invis's as you move.
;
; 1.6 - Dumpy - Altered code to allow limiting pick attempts before ignoring the chest
;
; 1.7 - fixed syntax bug which didn't allow disabling Invis (stupid space after
; equals sign was missing)
;
;==================================
initevents
;==================================
; CONFIGURATION
;==================================
; use hiding? (0=no 1=yes)
set %usehide 1
; use invis? (0=no 1=yes)
set %useinvis 0
; move to corner? (0=no 1=yes)
set %movetocorner 0
; set limit on number of attempts to pick chest before ignoring
; (set to 0 for no limit)
set %maxattempts 0
; Manual set up itemid of static chests (NOT NEEDED TO RUN)
set %static1 xxxxxxx
set %static2 xxxxxxx
set %static3 xxxxxxx
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
event macro 31 0
WAIT 10
event macro 8 1
wait 15
contpos 844 487
wait 15
event macro 8 7
wait 15
set %backpack #contid
contpos 772 -45
wait 10
event macro 8 2
wait 10
event macro 10 2
wait 10
contpos 805 160
set %backpackX 990
set %backpackY 700
set %chesttype IIF_IKF_KIF_HIF_JIF_BUD
set %htime 0
set %checkweight #maxweight - 10
set %loot 1
ignoreitem %static1
ignoreitem %static2
ignoreitem %static3
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
begin:
Finditem %chesttype
wait 10
;found a chest?
if #findkind = -1
{
gosub corner
goto begin
}
MOVETOCHEST:
event pathfind #FINDX #FINDY
set %returnx #findx
set %returny #findy
set %chest #findid
set %chesty #findy
wait 2s
finditem %chest
if #finddist > 2
goto movetochest
;set last target, use lockpick,
; wait for target, target last
set #ltargetid %chest
set %pickattempts 0
pick:
if %maxattempts > 0 && %pickattempts > %maxattempts
{
ignoreitem %chest
goto begin
}
set %pickattempts %pickattempts + 1
gosub lockpicks
target
set #ltargetkind 1
event macro 22 0
wait 2s
; cant pick?
scanjournal 1
if unable in #journal
goto pick
;if GET in #journal
; goto begin
;
;unlocked already?
;if DOES in #journal
else
{
ignoreitem %chest
goto begin
}
if %loot = 0
{
ignoreitem %chest
goto begin
}
;move away from chest
if %chestY > 824
goto here
if %chestY < 825
goto there
back:
event pathfind %returnx %returny
wait 2s
findItem %chest
if #findKind = -1
goto begin
if #findDist > 2
goto back
;use lastitem
set #lobjectid #ltargetid
event macro 17 0
wait 2s
contpos 50 50
wait 2s
gosub goldhunt
click 100 100 r
if #weight > %checkweight
set %loot 0
ignoreitem %chest
goto begin
here:
event pathfind 1017 819
wait 2s
finditem %chest
if #finddist > 4
{
gosub Telek
WAIT 3S
goto back
}
goto here
there:
event pathfind 1017 829
wait 2s
finditem %chest
if #finddist > 4
{
gosub Telek
WAIT 3S
goto back
}
GOTO THERE
sub Corner
If #charPosX = 1014 && #charPosY = 820
goto CHide
if %movetocorner = 1
event pathfind 1014 820
CHide:
if %usehide = 0
goto CInvis
IF H in #CHARSTATUS
return
set %ctime %htime + 12
if #time > %ctime
{
EVENT MACRO 13 21
set %htime #time
}
CInvis:
if %useinvis = 0
return
IF H in #CHARSTATUS
return
set %ctime %htime + 12
if #time > %ctime
{
event macro 15 43
target 7s
event macro 23
set %htime #time
}
return
sub goldhunt
search:
finditem POF C
if -1 in #findkind
return
if #findbagid = %backpack
{
ignoreitem #findid
goto search
}
move:
event drag #findid
wait 1s
msg $
click %backpackx %backpacky p
wait 1s
goto search
sub Telek
;cast telek on last target
event macro 15 20
target
event macro 22 0
return
sub lockpicks
sp:
;find lockpicks
finditem NWH
if #findkind = -1
{
msg Out of picks
halt
}
If #findbagid <> %backpack
{
ignoreitem #findid
goto sp
}
set %lockpick #findid
wait 2
set #lobjectid %lockpick
wait 2
event macro 17 0
return
Эээх, скриптеры, ГМов на вас нет... я вот скил честно в Веспере в банке качала, ручками... :-Р Вот такая я честная 
